configure.ac

   1 # Copyright (C) 2011, Antoine Bertin <diaoulael@gmail.com>
   2 #
   3 #  All rights reserved.
   4 #
   5 #  Redistribution and use in source and binary forms, with or without
   6 #  modification, are permitted provided that the following conditions
   7 #  are met:
   8 #
   9 #  - Redistributions of source code must retain the above copyright notice,
  10 #    this list of conditions and the following disclaimer.
  11 #  - Redistributions in binary form must reproduce the above copyright notice,
  12 #    this list of conditions and the following disclaimer in the documentation
  13 #    and/or other materials provided with the distribution.
  14 #  - Neither the name of the Developers nor the names of its contributors may
  15 #    be used to endorse or promote products derived from this software without
  16 #    specific prior written permission.
  17 #
  18 #  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  19 #  ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  20 #  LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  21 #  A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR
  22 #  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  23 #  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  24 #  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  25 #  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  26 #  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  27 #  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  28 #  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29
  30 # Process this file with autoconf to produce a configure script.
  31 AC_PREREQ([2.63])
  32 AC_INIT([umurmur], [0.2.11], [http://code.google.com/p/umurmur/issues/entry], [umurmur], [http://code.google.com/p/umurmur])
  33 AC_CONFIG_SRCDIR([src/client.h])
  34 AC_CONFIG_HEADERS([config.h])
  35 AM_INIT_AUTOMAKE
  36
  37 # Configure options.
  38 AC_ARG_WITH([ssl], [AC_HELP_STRING([--with-ssl=@<:@LIB@:>@], [SSL library (openssl|polarssl) @<:@default=polarssl@:>@])], [], [with_ssl=polarssl])
  39 AC_ARG_ENABLE(polarssl-test-cert, [  --enable-polarssl-test-cert  Link to PolarSSL test certificate and key @<:@default=no@:>@], [enable_polarssl_test_cert=yes])
  40 AC_ARG_ENABLE(polarssl-havege, [  --enable-polarssl-havege  Link to PolarSSL HAVEGE random generator key @<:@default=no@:>@ Deafult: /dev/urandom], [enable_polarssl_havege=yes])
  41
  42 # Checks for programs.
  43 AC_PROG_CC
  44
  45 # Checks dependencies.
  46 AC_CHECK_HEADERS([google/protobuf-c/protobuf-c.h], [], [AC_MSG_ERROR([could not find google/protobuf-c/protobuf-c.h])])
  47 AC_CHECK_LIB([protobuf-c], [protobuf_c_data_buffer_init], [], [AC_MSG_ERROR([could not find protobuf-c library])])
  48 AC_CHECK_HEADERS([libconfig.h], [], [AC_MSG_ERROR([could not find libconfig.h])])
  49 AC_CHECK_LIB([config], [config_init], [], [AC_MSG_ERROR([could not find libconfig])])
  50 AS_IF([test "x$with_ssl" = xpolarssl], [
  51         AC_CHECK_HEADERS([polarssl/ssl.h], [], [AC_MSG_ERROR([could not find polarssl/ssl.h])])
  52         AC_CHECK_LIB([polarssl], [ssl_init], [], [AC_MSG_ERROR([could not find libpolarssl])])
  53         AC_DEFINE([USE_POLARSSL], [], [Use PolarSSL])
  54     AS_IF([test "x$enable_polarssl_test_cert" = xyes], [
  55             AC_CHECK_LIB([polarssl], [test_srv_crt], [], [AC_MSG_ERROR([could not find test_srv_crt])])
  56             AC_DEFINE([USE_POLARSSL_TESTCERT], [], [Use PolarSSL test certificate])
  57     ])
  58     AS_IF([test "x$enable_polarssl_havege" = xyes], [
  59             AC_CHECK_LIB([polarssl], [havege_init], [], [AC_MSG_ERROR([could not find havege_init])])
  60             AC_DEFINE([USE_POLARSSL_HAVEGE], [], [Use PolarSSL HAVEGE random generator])
  61     ])
  62 ])
  63 AS_IF([test "x$with_ssl" = xopenssl], [
  64         AC_CHECK_HEADERS([openssl/ssl.h], [], [AC_MSG_ERROR([could not find openssl/ssl.h])])
  65         AC_CHECK_LIB([crypto], [BN_init], [], [AC_MSG_ERROR([could not find libcrypto])])
  66         AC_CHECK_LIB([ssl], [SSL_library_init], [], [AC_MSG_ERROR([could not find libssl])])
  67 ])
  68
  69 # Checks for header files.
  70 AC_FUNC_ALLOCA
  71 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/tcp.h stddef.h stdint.h stdlib.h string.h sys/socket.h sys/time.h syslog.h unistd.h sys/poll.h], [], [AC_MSG_ERROR([missing a required header])])
  72
  73 # Checks for typedefs, structures, and compiler characteristics.
  74 AC_HEADER_STDBOOL
  75 AC_TYPE_UID_T
  76 AC_C_INLINE
  77 AC_TYPE_INT32_T
  78 AC_TYPE_INT64_T
  79 AC_TYPE_SIZE_T
  80 AC_TYPE_UINT16_T
  81 AC_TYPE_UINT32_T
  82 AC_TYPE_UINT64_T
  83 AC_TYPE_UINT8_T
  84
  85 # Checks for library functions.
  86 AC_CHECK_FUNCS([ftruncate gettimeofday inet_ntoa memchr memmove memset socket strdup strerror strrchr uname poll], [], [AC_MSG_ERROR([missing a required func])])
  87
  88 AC_CONFIG_FILES([Makefile src/Makefile])
  89 AC_OUTPUT