bootloader: Rename bootloader.ld to bootloader-intermediate.ld.

[gps-watch.git] / src / bootloader / bootloader.ld

diff --git a/src/bootloader/bootloader.ld b/src/bootloader/bootloader.ld
deleted file mode 100644 (file)
index 55b6057..0000000
--- a/src/bootloader/bootloader.ld
+++ /dev/null
@@ -1,162 +0,0 @@
-/* This is a copy of
- *   CMSIS/Device/ARM/ARMCM0plus/Source/GCC/gcc_arm.ld
- * taken from
- *   git://github.com/ARM-software/CMSIS
- */
-
-/* Linker script to configure memory regions. */
-MEMORY
-{
-  FLASH (rx)
-    : ORIGIN = 0x00008000, LENGTH = 0x38000
-
-  RAM (rwx)
-    : ORIGIN = 0x1fffe000, LENGTH = 0x08000
-}
-
-/* Library configurations */
-GROUP(libgcc.a libc.a libm.a libnosys.a)
-
-/* Linker script to place sections and symbol values. Should be used together
- * with other linker script that defines memory regions FLASH and RAM.
- * It references following symbols, which must be defined in code:
- *   Reset_Handler : Entry of reset handler
- *
- * It defines following symbols, which code can use without definition:
- *   __exidx_start
- *   __exidx_end
- *   __etext
- *   __data_start__
- *   __preinit_array_start
- *   __preinit_array_end
- *   __init_array_start
- *   __init_array_end
- *   __fini_array_start
- *   __fini_array_end
- *   __data_end__
- *   __bss_start__
- *   __bss_end__
- *   __end__
- *   end
- *   __HeapLimit
- *   __StackLimit
- *   __StackTop
- *   __stack
- */
-ENTRY(Reset_Handler)
-
-SECTIONS
-{
-       .text :
-       {
-               KEEP(*(.vectors))
-               __end__ = .;
-
-               *(.text*)
-
-               KEEP(*(.init))
-               KEEP(*(.fini))
-
-               /* .ctors */
-               *crtbegin.o(.ctors)
-               *crtbegin?.o(.ctors)
-               *(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors)
-               *(SORT(.ctors.*))
-               *(.ctors)
-
-               /* .dtors */
-               *crtbegin.o(.dtors)
-               *crtbegin?.o(.dtors)
-               *(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors)
-               *(SORT(.dtors.*))
-               *(.dtors)
-
-               *(.rodata*)
-
-               KEEP(*(.eh_frame*))
-       } > FLASH
-
-       .ARM.extab :
-       {
-               *(.ARM.extab* .gnu.linkonce.armextab.*)
-       } > FLASH
-
-       __exidx_start = .;
-       .ARM.exidx :
-       {
-               *(.ARM.exidx* .gnu.linkonce.armexidx.*)
-       } > FLASH
-       __exidx_end = .;
-
-       __etext = .;
-
-       .data : AT (__etext)
-       {
-               __data_start__ = .;
-               *(vtable)
-               *(.data*)
-
-               . = ALIGN(4);
-               /* preinit data */
-               PROVIDE_HIDDEN (__preinit_array_start = .);
-               KEEP(*(.preinit_array))
-               PROVIDE_HIDDEN (__preinit_array_end = .);
-
-               . = ALIGN(4);
-               /* init data */
-               PROVIDE_HIDDEN (__init_array_start = .);
-               KEEP(*(SORT(.init_array.*)))
-               KEEP(*(.init_array))
-               PROVIDE_HIDDEN (__init_array_end = .);
-
-
-               . = ALIGN(4);
-               /* finit data */
-               PROVIDE_HIDDEN (__fini_array_start = .);
-               KEEP(*(SORT(.fini_array.*)))
-               KEEP(*(.fini_array))
-               PROVIDE_HIDDEN (__fini_array_end = .);
-
-               KEEP(*(.jcr*))
-               . = ALIGN(4);
-               /* All data end */
-               __data_end__ = .;
-
-       } > RAM
-
-       .bss :
-       {
-               . = ALIGN(4);
-               __bss_start__ = .;
-               *(.bss*)
-               *(COMMON)
-               . = ALIGN(4);
-               __bss_end__ = .;
-       } > RAM
-
-       .heap (COPY):
-       {
-               __HeapBase = .;
-               __end__ = .;
-               end = __end__;
-               KEEP(*(.heap*))
-               __HeapLimit = .;
-       } > RAM
-
-       /* .stack_dummy section doesn't contains any symbols. It is only
-        * used for linker to calculate size of stack sections, and assign
-        * values to stack symbols later */
-       .stack_dummy (COPY):
-       {
-               KEEP(*(.stack*))
-       } > RAM
-
-       /* Set stack top to end of RAM, and stack limit move down by
-        * size of stack_dummy section */
-       __StackTop = ORIGIN(RAM) + LENGTH(RAM);
-       __StackLimit = __StackTop - SIZEOF(.stack_dummy);
-       PROVIDE(__stack = __StackTop);
-
-       /* Check if data + heap + stack exceeds RAM limit */
-       ASSERT(__StackLimit >= __HeapLimit, "region RAM overflowed with stack")
-}