contrib/pulseview_cross.nsi

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2013-2014 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, write to the Free Software
  18 ## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  19 ##
  20
  21 #
  22 # This file is used to create the PulseView Windows installer via NSIS.
  23 # It is meant for use in a cross-compile setup (not for native builds).
  24 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  25 #
  26 # NSIS documentation:
  27 # http://nsis.sourceforge.net/Docs/
  28 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  29 #
  30
  31 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  32 !include "MUI2.nsh"
  33
  34
  35 # --- Global stuff ------------------------------------------------------------
  36
  37 # Installer/product name.
  38 Name "PulseView"
  39
  40 # Filename of the installer executable.
  41 OutFile "pulseview-0.2.0-installer.exe"
  42
  43 # Where to install the application.
  44 InstallDir "$PROGRAMFILES\sigrok\PulseView"
  45
  46 # Request admin privileges for Windows Vista and Windows 7.
  47 # http://nsis.sourceforge.net/Docs/Chapter4.html
  48 RequestExecutionLevel admin
  49
  50 # Local helper definitions.
  51 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\PulseView"
  52
  53
  54 # --- MUI interface configuration ---------------------------------------------
  55
  56 # Use the following icon for the installer EXE file.
  57 !define MUI_ICON "../icons/sigrok-logo-notext.ico"
  58
  59 # Show a nice image at the top of each installer page.
  60 !define MUI_HEADERIMAGE
  61
  62 # Don't automatically go to the Finish page so the user can check the log.
  63 !define MUI_FINISHPAGE_NOAUTOCLOSE
  64
  65 # Upon "cancel", ask the user if he really wants to abort the installer.
  66 !define MUI_ABORTWARNING
  67
  68 # Don't force the user to accept the license, just show it.
  69 # Details: http://trac.videolan.org/vlc/ticket/3124
  70 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  71 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  72
  73 # Path where the cross-compiled sigrok tools and libraries are located.
  74 # Change this to where-ever you installed libsigrok.a and so on.
  75 !define CROSS "$%HOME%/sr_mingw"
  76
  77 # Path where the cross-compiled MXE tools and libraries are located.
  78 # Change this to where-ever you installed MXE (and the files it built).
  79 !define MXE "$%HOME%/mxe-git/usr/i686-pc-mingw32"
  80
  81
  82 # --- MUI pages ---------------------------------------------------------------
  83
  84 # Show a nice "Welcome to the ... Setup Wizard" page.
  85 !insertmacro MUI_PAGE_WELCOME
  86
  87 # Show the license of the project.
  88 !insertmacro MUI_PAGE_LICENSE "../COPYING"
  89
  90 # Show a screen which allows the user to select which components to install.
  91 !insertmacro MUI_PAGE_COMPONENTS
  92
  93 # Allow the user to select a different install directory.
  94 !insertmacro MUI_PAGE_DIRECTORY
  95
  96 # Perform the actual installation, i.e. install the files.
  97 !insertmacro MUI_PAGE_INSTFILES
  98
  99 # Show a final "We're done, click Finish to close this wizard" message.
 100 !insertmacro MUI_PAGE_FINISH
 101
 102 # Pages used for the uninstaller.
 103 !insertmacro MUI_UNPAGE_WELCOME
 104 !insertmacro MUI_UNPAGE_CONFIRM
 105 !insertmacro MUI_UNPAGE_INSTFILES
 106 !insertmacro MUI_UNPAGE_FINISH
 107
 108
 109 # --- MUI language files ------------------------------------------------------
 110
 111 # Select an installer language (required!).
 112 !insertmacro MUI_LANGUAGE "English"
 113
 114
 115 # --- Default section ---------------------------------------------------------
 116
 117 Section "PulseView (required)" Section1
 118
 119         # This section is gray (can't be disabled) in the component list.
 120         SectionIn RO
 121
 122         # Install the file(s) specified below into the specified directory.
 123         SetOutPath "$INSTDIR"
 124
 125         # License file.
 126         File "../COPYING"
 127
 128         # PulseView (statically linked, includes all libs).
 129         File "${CROSS}/bin/pulseview.exe"
 130
 131         # Zadig (used for installing WinUSB drivers).
 132         File "${CROSS}/zadig.exe"
 133         File "${CROSS}/zadig_xp.exe"
 134
 135         # Python
 136         File "${CROSS}/python32.dll"
 137         File "${CROSS}/python32.zip"
 138
 139         # Protocol decoders.
 140         SetOutPath "$INSTDIR\decoders"
 141         File /r /x "__pycache__" "${CROSS}/share/libsigrokdecode/decoders/*"
 142
 143         # Firmware files.
 144         SetOutPath "$INSTDIR\firmware"
 145         File /r "${CROSS}/share/sigrok-firmware/*"
 146
 147         # Example *.sr files.
 148         SetOutPath "$INSTDIR\examples"
 149         File /r "${CROSS}/share/sigrok-dumps/*"
 150
 151         # Generate the uninstaller executable.
 152         WriteUninstaller "$INSTDIR\Uninstall.exe"
 153
 154         # Create a sub-directory in the start menu.
 155         CreateDirectory "$SMPROGRAMS\sigrok"
 156         CreateDirectory "$SMPROGRAMS\sigrok\PulseView"
 157
 158         # Create a shortcut for the PulseView application.
 159         SetOutPath "$INSTDIR"
 160         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" \
 161                 "$INSTDIR\pulseview.exe" "" "$INSTDIR\pulseview.exe" \
 162                 0 SW_SHOWNORMAL \
 163                 "" "Open-source, portable sigrok GUI"
 164
 165         # Create a shortcut for the uninstaller.
 166         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk" \
 167                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 168                 SW_SHOWNORMAL "" "Uninstall PulseView"
 169
 170         # Create registry keys for "Add/remove programs" in the control panel.
 171         WriteRegStr HKLM "${REGSTR}" "DisplayName" "PulseView"
 172         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 173                 "$\"$INSTDIR\Uninstall.exe$\""
 174         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 175         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 176                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
 177         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 178         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 179                 "http://sigrok.org/wiki/PulseView"
 180         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 181                 "http://sigrok.org/wiki/Downloads"
 182         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 183         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "0.2.0"
 184         WriteRegStr HKLM "${REGSTR}" "Contact" \
 185                 "sigrok-devel@lists.sourceforge.org"
 186         WriteRegStr HKLM "${REGSTR}" "Comments" \
 187                 "This is a Qt based sigrok GUI."
 188
 189         # Display "Remove" instead of "Modify/Remove" in the control panel.
 190         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 191         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 192
 193 SectionEnd
 194
 195
 196 # --- Uninstaller section -----------------------------------------------------
 197
 198 Section "Uninstall"
 199
 200         # Always delete the uninstaller first (yes, this really works).
 201         Delete "$INSTDIR\Uninstall.exe"
 202
 203         # Delete the application, the application data, and related libs.
 204         Delete "$INSTDIR\COPYING"
 205         Delete "$INSTDIR\pulseview.exe"
 206         Delete "$INSTDIR\zadig.exe"
 207         Delete "$INSTDIR\zadig_xp.exe"
 208         Delete "$INSTDIR\python32.dll"
 209         Delete "$INSTDIR\python32.zip"
 210
 211         # Delete all decoders and everything else in decoders/.
 212         # There could be *.pyc files or __pycache__ subdirs and so on.
 213         RMDir /r "$INSTDIR\decoders\*"
 214
 215         # Delete the firmware files.
 216         RMDir /r "$INSTDIR\firmware\*"
 217
 218         # Delete the example *.sr files.
 219         RMDir /r "$INSTDIR\examples\*"
 220
 221         # Delete the install directory and its sub-directories.
 222         RMDir "$INSTDIR\decoders"
 223         RMDir "$INSTDIR\firmware"
 224         RMDir "$INSTDIR\examples"
 225         RMDir "$INSTDIR"
 226
 227         # Delete the links from the start menu.
 228         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk"
 229         Delete "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk"
 230
 231         # Delete the sub-directory in the start menu.
 232         RMDir "$SMPROGRAMS\sigrok\PulseView"
 233         RMDir "$SMPROGRAMS\sigrok"
 234
 235         # Delete the registry key(s).
 236         DeleteRegKey HKLM "${REGSTR}"
 237
 238 SectionEnd
 239
 240
 241 # --- Component selection section descriptions --------------------------------
 242
 243 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the PulseView sigrok GUI, some firmware files, the protocol decoders, some example files, and all required libraries."
 244
 245 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 246 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 247 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 248